<%@ Language=VBScript %>
<%
Option Explicit
Response.Expires = 0
On Error Resume Next
%>
<%
'*****************************************************************
'Variablendeklarationen
Dim intaktuellersatz
Dim intmaxpaginglength
Dim intpage 'nötig, weil sich absolutepage zwar setzen, aber nicht auslesen lässt
Dim intpagingfirst
Dim intpaginglast
Dim objcon
Dim objrs
Dim strcon
Dim strfilename
Dim strsqlsel
'*****************************************************************
'Variableninitialisierung
'Seite in Parameter abfragen und setzen -> auch in title verwendet!
intpage = 1
If Request.QueryString("parpage") > 0 Then
intpage = CInt(Request.QueryString("parpage"))
End If 'Request.QueryString("parpage") > 0
'Länge der Seite
intmaxpaginglength = 24
'Dateinamen der aufrufenden Seite holen
strfilename = right(request.servervariables("PATH_TRANSLATED"), _
Len(request.servervariables("PATH_TRANSLATED")) _
- InStrRev(request.servervariables("PATH_TRANSLATED"),"\"))
'Objekte für DB-Verbindung erstellen
Set objcon = Server.CreateObject("ADODB.Connection")
Set objrs = Server.CreateObject("ADODB.Recordset")
'*****************************************************************
'Lokale Prozeduren und Funktionen
'*****************************************************************
'Anfang Code
strcon = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
server.mappath("/asppages/silvi/db/url2002.mdb") & ";User ID=admin;Password=;"
'strcon = "DRIVER={Microsoft Access Driver (*.mdb)}; " & _
' "DBQ=" & Server.MapPath("/asppages/silvi/db/url2002.mdb") & ";UID=admin;PWD=;"
objcon.Open strcon
strsqlsel = "SELECT url, name from url"
objrs.Open strsqlsel, objcon, 3, 3
'*****************************************************************
'Anfang <html>
%>
<!--#include virtual="asppages/silvi/_include/preheader.inc" -->
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252" />
<title>ASP fortgeschrittene DB-Techniken: Anzeige eines Recordsets mit Paging - Seite
<%=intpage%></title>
<meta name="description" content="" />
<meta name="keywords" content="" />
<!--#include virtual="asppages/silvi/_include/header.inc" -->
</head>
<body>
<%
'*****************************************************************
'Code innerhalb der HTML-Seite
'Gültiges, geöffnetes Recordset?
If TypeName(objrs) = "Recordset" And objrs.state = 1 Then
'Treffer anzeigen
intpagingfirst = (intpage - 1) * intmaxpaginglength + 1
If objrs.RecordCount > intpage * intmaxpaginglength Then
intpaginglast = intpage * intmaxpaginglength
Else
intpaginglast = objrs.RecordCount
End If
Response.Write(space(6)& "<p><b>Treffer " & intpagingfirst & " bis " & _
intpaginglast & " von " & objrs.recordcount & "</b></p>" & vbCrLf)
If objrs.RecordCount > intmaxpaginglength Then
'Paging: Länge der Seite setzen
objrs.PageSize = intmaxpaginglength
objrs.AbsolutePage = intpage
For intaktuellersatz = 1 To objrs.PageSize
If Not objrs.EOF Then
Response.Write("<a href=""" & objrs("url") & """>" & objrs("name") & _
"</a><br />" & vbCrLf)
objrs.MoveNext
End If
Next
Response.Write(" <br />"&vbCrLf)
'Links zum Vor- und Zurückblättern
If intpage > 1 Then
Response.Write("<a href=""" & strfilename & _
"?parpage=" & intpage - 1 & _
""">Eine Seite zurück</a> " & vbCrLf)
End If
If intpage < objrs.PageCount Then
Response.Write("<a href=""" & strfilename & _
"?parpage=" & intpage + 1 &_
""">Eine Seite weiter</a> " & vbCrLf)
End If
Response.Write("<br />"&vbCrLf)
Else
While Not objrs.EOF
Response.Write("<a href=""" & objrs("url") & """>" & objrs("name") &_
"</a><br />" & vbCrLf)
objrs.MoveNext
Wend
End If 'objrs.RecordCount > intmaxpaginglength
End If 'TypeName(objrs) = "Recordset" And objrs.state = 1
'Recordset und Connection schliessen
objrs.Close
set objrs = Nothing
objcon.Close
set objcon = Nothing
%>
<!--#include virtual="asppages/silvi/_include/inchtmlnachspann.asp" -->
</body>
</html>
Demo: beispiele/065dbpaging.asp
Letzter Update:
26.12.2021 17:48
Zurück zur
Liste mit ASP-Beispielen auf
www.ecotronics.ch