<%@ Language=VBScript %>
<%
Option Explicit
Response.Expires = 0
On Error Resume Next


'*****************************************************************
'Anfang <html>
%>

<!--#include virtual="asppages/silvi/_include/preheader.inc" -->
<html>
  <head>
    <title>ASP fortgeschrittene DB-Techniken: Anzeige von Master- und Detaildatensätzen mit MSDataShape</title>
<!--#include virtual="asppages/silvi/_include/header.inc" -->
  </head>
<body>
<h3>Anzeige von Master- und Detaildatensätzen mit MSDataShape</h3>
<%
'*****************************************************************
'Code innerhalb der HTML-Seite

Dim objcon
Dim objrsmaster
Dim objrsdetail
Dim strsql
Set objcon = Server.CreateObject("ADODB.Connection")
objcon.open "Provider=MSDataShape;Data Provider=Microsoft.Jet.OLEDB.4.0;" & _
  "Data Source=" & server.MapPath("/asppages/silvi/db/dbartikel2000.mdb")

Set objrsmaster = Server.CreateObject("ADODB.Recordset")

strsql = "SHAPE {SELECT * FROM tblkategorien} " & vbCrLf & _
  "APPEND ({SELECT * FROM tblartikel} AS detail " & vbCrLf & _
  "RELATE kategorienr TO kategorienr)"

objrsmaster.StayInSync = FALSE
objrsmaster.Open strsql, objcon

Do While Not objrsmaster.EOF
  Response.Write("<p><b>" & objrsmaster("kategoriename") & "</b><br />" & vbCrLf)
  'Das .value ist unbedingt nötig!
  Set objrsdetail = objrsmaster("detail").value
  Do While Not objrsdetail.EOF
    Response.Write("&nbsp;&nbsp;" & objrsdetail("artikelname") & "<br />" & vbCrLf)
    objrsdetail.MoveNext
  Loop
  objrsmaster.MoveNext
Loop


objrsmaster.Close
objrsdetail.close
Set objrsmaster = Nothing
Set objrsdetail = Nothing
%>

<!--#include virtual="asppages/silvi/_include/inchtmlnachspann.asp" -->
</body>
</html>

Demo: beispiele/065masterdetail.asp

Letzter Update: 26.12.2021 16:48

Zurück zur Liste mit ASP-Beispielen auf  www.ecotronics.ch