<%@ Language=VBScript %>
<%
Option Explicit
Response.Expires = 0
On Error Resume Next

'*****************************************************************
'Variablendeklarationen
Dim arrintnumbers
Dim arrstrbez
Dim arrelement


'*****************************************************************
'Variableninitialisierung
arrstrbez = Array("WebMaster/in","WebPublisher/in", _
  "PC-Supporter/in", "Netzwerkspezialist/in", "Applikationsentwickler/in")

arrintnumbers = Array(6,5,4,3,2,1)


'*****************************************************************
'Lokale Prozeduren und Funktionen
Sub procarrbubblesort (ByRef arrvar)
  Dim blnallesok
  Dim intcounter
  Dim strhelp
  
  Response.Write(UBound(arrvar) & "<br />" & vbCrLf)
  Do
    blnallesok = true
    For intcounter = 0 to UBound(arrvar) - 1
      if arrvar(intcounter) > arrvar(intcounter+1) then
        strhelp = arrvar(intcounter)
        arrvar(intcounter) = arrvar(intcounter+1)
        arrvar(intcounter+1) = strhelp
        blnallesok = false
      end if
    Next
  Loop While blnallesok = false
End Sub

'*****************************************************************
'Anfang Code


'*****************************************************************
'Anfang <html>
%>
<!--#include virtual="asppages/silvi/_include/preheader.inc" -->
<html>
  <head>
    <title>ASP nützliche Routinen: Array sortieren mit Bubblesort</title>
    <meta name="description" content="" />
    <meta name="keywords" content="ASP, Bubblesort, sortieren" />
<!--#include virtual="asppages/silvi/_include/header.inc" -->
  </head>
<body>
<%
'*****************************************************************
'Code innerhalb der HTML-Seite
Response.Write("<p><b>Strings sortieren mit Bubblesort</b></p>")
Response.Write("<i>Vor Sortierung:</i><br />")
For each arrelement in arrstrbez
  Response.Write(arrelement & "<br />" & vbCrLf)
Next

call procarrbubblesort(arrstrbez)

Response.Write("&nbsp;<br /><i>Nach Sortierung:</i><br />")
For each arrelement in arrstrbez
  Response.Write(arrelement & "<br />" & vbCrLf)
Next

'Zahlen sortieren
Response.Write("&nbsp;<br /><p><b>Zahlen sortieren mit Bubblesort</b></p>")
Response.Write("<i>Vor Sortierung:</i><br />")
For each arrelement in arrintnumbers
  Response.Write(arrelement & "<br />" & vbCrLf)
Next

call procarrbubblesort(arrintnumbers)

Response.Write("<i>&nbsp;<br />Nach Sortierung:</i><br />")
For each arrelement in arrintnumbers
  Response.Write(arrelement & "<br />" & vbCrLf)
Next
%>
<!--#include virtual="asppages/silvi/_include/inchtmlnachspann.asp" -->
</body>
</html>

Demo: beispiele/070bubblesortonedimensionalarray.asp
Letzter Update: 26.12.2021 17:48

Zurück zur Liste mit ASP-Beispielen auf  www.ecotronics.ch