rothen ecotronics Bern: ASP-Skript "ASP Datenbankanbindung: Auslesen von Datensätzen"

<%@ Language=VBScript %>
<%
Option Explicit
Response.Expires = 0
On Error Resume Next

'Default, nur vorwärts scrollbar, nicht änderbar, Änderungen anderer User nicht sichtbar
Const adOpenForwardOnly = 0 'Default

'Änderbar, vorwärts- und rückwärts scrollbar, Änderungen anderer User nicht sichtbar
Const adOpenKeyset = 1

'Änderbar, vorwärts- und rückwärts scrollbar, Änderungen anderer User sichtbar
'Dieser Cursor wird nicht von allen Datenbanken unterstützt!
Const adOpenDynamic = 2

'Nicht änderbar, vorwärts- und rückwärts scrollbar, Änderungen anderer User nicht sichtbar
Const adOpenStatic = 3

'---- LockTypeEnum Values ----
'Nicht änderbar
Const adLockReadOnly = 1 'Default

'Records werden bereits beim Einlesen gesperrt
Const adLockPessimistic = 2

'Records werden nur beim Aufdatieren gesperrt
Const adLockOptimistic = 3

'Records werden nur beim Batch-Update gesperrt
Const adLockBatchOptimistic = 4

Dim objcon, objrspersonen, strsqlselpersonen

'*****************************************************************
'Anfang <html>
%>
<html>
  <head>
    <meta http-equiv="Content-Type" content="text/html; charset=windows-1252" />
    <title>ASP Datenbankanbindung: Auslesen von Datensätzen</title>
  </head>
<body>
<%
'*****************************************************************
'Code innerhalb der HTML-Seite

Set objcon = Server.CreateObject("ADODB.Connection")
'Mit ODBC
'objcon.Open "DSN=dsnpersonen"

'ohne ODBC
'objcon.Open "DRIVER={Microsoft Access Driver (*.mdb)}; " & _
'  "DBQ=" & server.MapPath("/asppages/silvi/db/dbpersonen2000.mdb")

'mit OLEDB
objcon.Open _
  "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
  server.mappath("/asppages/silvi/db/dbpersonen2000.mdb")

'Select
strsqlselpersonen = "SELECT * FROM tblpersonen "
Set objrspersonen = Server.CreateObject("ADODB.Recordset")
objrspersonen.Open strsqlselpersonen, objcon, adOpenKeyset, adLockOptimistic

Do While Not objrspersonen.EOF
  Response.Write(objrspersonen("vorname")&" "&objrspersonen("nachname")&"<br />"&vbcrlf)
  objrspersonen.MoveNext
Loop
Response.Write("<p />"&vbCrLf)

objrspersonen.Close
Set objrspersonen = Nothing
%>

</body>
</html>

Demo: uebungen/uebung6_6select.asp

Letzter Update: 26.12.2021 17:48

Zurück zur Liste mit ASP-Übungen auf www.ecotronics.ch